To write code for your application that parses HL7 messages, you first need to know what classes are created when you use your Chameleon VMD file to generate VB.NET stubcode for your application.

• The Engine class represents the Chameleon engine that parses and classifies the HL7 messages.
• The Message class represents a message definition you specified in the VMD file. One Message class is created for each message definition in the file. These classes are accessible from the Engine class.
• The Table class represents a table you created when building the VMD file. This class enables you to access any row of the table. One Table class is created for each table you define.
• The TableRow class represents a row of its table. TableRow objects are accessed from the Table class. One TableRow class is created for each table you define.

In this example, the following classes have been created:

• The Engine class: in the example, this class is named HL7Engine, since you specified HL7 as the last part of the prefix when generating your stubcode.
• One Message class: this class is named PatientRegisterMessage, since the message definition in the VMD file is named PatientRegister.
• One Table class: this class is named PatientTable, since the table in the VMD file is named Patient.
• One TableRow class, named PatientTableRow and associated with the PatientTable class.

Now that you have this information, you are ready to write the VB.NET code for the sample application. Recall that the sample application contains:

• A text box named HL7Message into which you type or copy HL7 messages to be parsed;
• A text box named ParsedOutput that will contain the parsed output;
• A button named ChangeButton that starts the parsing process.

The Sample Form

The following VB.NET code example implements HL7 message parsing in this sample application:

Imports System
Imports System.Text
Imports iNTERFACEWARE.Chameleon
Imports vbnet.server.HL7

Public Class Form1
    Dim Engine As SampleVbnetServerEngine = New SampleVbnetServerEngine

    Private Sub ChangeButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ChangeButton.Click
        Dim ParseString As New StringBuilder()
        ParseString.Append(HL7Message.Text)
        ParseString.Replace(ControlChars.Lf, "")
        Engine.ParseMessage(ParseString.ToString(), Nothing)
    End Sub
End Class

Class SampleVbnetServerEngine
    Inherits HL7Engine

    Sub New()
        MyBase.Load("D:\sample\vbnet_server.vmd")
    End Sub

    Public Overrides Sub ParseMessage(ByVal flatwire As String, ByVal aTransport As Transport)
        Try
            MyBase.ParseMessage(flatwire, aTransport)
        Catch ex As ChameleonException
            ErrorEvent(ex, "Error parsing message")
        Catch ex As Exception
            ErrorEvent(ex, "General exception")
        End Try
    End Sub

    Public Overrides Sub OnPatientRegisterMessage(ByVal aMessage As PatientRegisterMessage, ByVal aTransport As Transport)
        Dim MsgOutput As String
        Dim CRLF As String
        CRLF = ControlChars.Cr + ControlChars.Lf
        Try
            MsgOutput = "PatientID: " + aMessage.Patient(0).PatientID.ToString() + CRLF _
                + "Surname: " + aMessage.Patient(0).Surname.ToString() + CRLF _
                + "GivenName: " + aMessage.Patient(0).FirstName.ToString() + CRLF _
                + "SSN: " + aMessage.Patient(0).SocialSecurityNumber.ToString() + CRLF
            Form1.ParsedOutput.Text = MsgOutput
        Catch ex As ChameleonException
            ErrorEvent(ex, "Error in PatientRegister message")
        End Try
    End Sub
End Class

Here, the SampleVbnetServerEngine class handles message parsing and the displaying of the parsed output. It inherits the methods of the HL7Engine class that was created by Chameleon. Three of these methods are used in this application:

• Load, which initializes the parsing engine to use the VMD file you created (this is called when the SampleVbnetServerEngine object is created);
• ParseMessage, which parses an HL7 message based on the information in the VMD file;
• OnPatientRegisterMessage, which is the method that is called when a PatientRegister message is successfully parsed.

Here is how the application works:

• The user types a message into the HL7Message field and presses the button to parse the message.
• The ChangeButton_Click method is called, which calls ParseMessage to parse the message.
• If a PatientRegister message is successfully parsed, the OnPatientRegisterMessage method is called. This method writes the message data into the ParsedOutput text box.

	When the user types or copies an HL7 message into the HL7Message field, each segment of the message is terminated by a carriage return character and a line feed character. Since the HL7 definition specifies that each segment of an HL7 message must be terminated by a carriage return only, the ChangeButton_Click method must strip the line feed characters from the message before it can be parsed.

And here is how OnPatientRegisterMessage accesses the message data:

• The aMessage variable contains the parsed message data. This is an instance of the PatientRegisterMessage class.
• From aMessage, you can access the Patient table and its rows. A table row contains the fields defined in the table you specified in your VMD file.
• From the table row, you can access the PatientID, Surname, FirstName and SocialSecurityNumber fields.

Now that you have written your application code, the final step is to test the application.