Imports iNTERFACEWARE.Chameleon
Imports iNTERFACEWARE.Iguana.Plugin

Module IguanaPlugin
   ' The SourcePluginExample is an example of an Iguana source plugin.
   Class SourcePluginExample
      Implements Log

      Public Sub New()
         ' The first step in making the generated HL7Engine object useable 
         ' is to load the message definition or 'vmd' file. This file contains
         ' the information about the structure of the messages, tables, and 
         ' data mappings that were defined in the Chameleon GUI. 
         '  
         ' HL7Engine is a generated engine which means that it has an interface
         ' based on the Messages and Tables you define in your vmd file. The 
         ' use of stub code is helpful since it means that the compiler can 
         ' catch typos or spelling mistakes of fields at compile rather than 
         ' run time. However, it is not the only way you can use Chameleon. It
         ' is possible to use a non-stubcode interface for the Chameleon
         ' engine which we call the 'dynamic interface'. Please review the 
         ' manual documentation for more details if you need this functionality
         ' - most customers find that the stub code interface works well for 
         ' their applications.

         engine.AddLog(Me)
         System.Console.WriteLine("Loading plugin_receive_test.vmd...")
         engine.Load("plugin_receive_test.vmd")
         engine.CurrentConfigIndex = 0
         System.Console.WriteLine("plugin_receive_test.vmd loaded")
      End Sub

      ' Log interface implementation.
      Sub Println(ByVal line As String) Implements Log.Println
         System.Console.WriteLine(line)
         logString += line
         logString += "\n"
      End Sub

      Private Function GenerateRandomMessage() As String
         Select Case random.Next(0, 1)
            Case 0
               Return (New GeneratePersonUpdate).GenerateMessage(engine)
            Case Else
               Return (New GeneratePersonUpdate).GenerateMessage(engine)
         End Select
      End Function

      ' This event is triggered when Iguana requests a message.
      Public Sub OnMessageRequested(ByVal sender As Object, _
                                    ByVal args As System.EventArgs, _
                                    ByVal inputs As SourceMessageRequestedEventInputs, _
                                    ByVal outputs As SourceMessageRequestedEventOutputs) Handles source.MessageRequested

         ' Note that exceptions can never be thrown outside the handler.
         Try
            Try
               System.Console.WriteLine("")
               System.Console.WriteLine("*** Message Requested ***")

               ' To simulate the behavior of a real-world plugin, we throttle the rate
               ' at which we generate messages to at most once per second.
               '
               ' Real world plugins need no such throttling mechanism.  Real-world plugins
               ' should respond to message requests immediately with either the next available 
               ' message, or an empty response if no messages are presently available.
               ' 
               ' When a plugin responds to a message request with an empty response (signifying
               ' that no messages are presently available), Iguana will delay for the period 
               ' specified by the channel's From Plugin component Polling Time setting before 
               ' sending another message request.

               Dim now As DateTime = DateTime.Now
               Dim generateMessage As Boolean = (now.Subtract(lastMessageRequestTime)).Seconds >= 1
               lastMessageRequestTime = now

               If generateMessage Then
                  ' Set OutboundMessage to next available message.
                  logString = ""
                  Dim outboundMessage As String = GenerateRandomMessage()
                  outputs.OutboundMessage = outboundMessage

                  ' Set PluginMessageId to a unique identifier for the message, which will
                  ' be sent back to the plugin in the next messageRequestCompleted event.
                  Dim pluginMessageId As String = lastMessageRequestTime.ToString()
                  outputs.PluginMessageId = pluginMessageId

                  System.Console.WriteLine("Message Generated (plugin message id: " + pluginMessageId + ")")
                  System.Console.WriteLine(outboundMessage.Replace("\r", "\n"))
               Else
                  System.Console.WriteLine("Responding with an empty message - no messages presently available.")
               End If
            Catch ex As Exception
               System.Console.WriteLine("Message Generation Error:")
               System.Console.WriteLine(ex.ToString())

               ' Add an error-level log message to Iguana's logs describing the failure.
               outputs.AddErrorLogMessage(ex.ToString())

               ' You could also use StopChannelFlag, StopChannelErrorFlag, and StopChannelReason 
               ' to stop the Iguana channel with or without an error flag, and provide a 
               ' reason for the stop request.
               '
               ' outputs.StopChannel = true
               ' outputs.StopChannelErrorFlag = true
               ' outputs.StopChannelReason = "An error occurred."
            End Try

            ' You can send additional error/warning/info/debug log messages to Iguana.
            ' In this case we simply send an info-level log message containing the 
            ' Chameleon engine's log output.
            If logString.Length <> 0 Then
               outputs.AddInfoLogMessage(logString)
            End If
         Catch ex As Exception
            System.Console.WriteLine(ex.ToString())
         End Try
      End Sub

      ' This event is received when Iguana has received the message sent via the previous MessageRequested event.
      Public Sub OnMessageRequestCompleted(ByVal sender As Object, _
                                           ByVal args As System.EventArgs, _
                                           ByVal inputs As SourceMessageRequestCompletedEventInputs, _
                                           ByVal outputs As SourceMessageRequestCompletedEventOutputs) Handles source.MessageRequestCompleted

         ' Note that exceptions can never be thrown outside the handler.
         Try
            ' PluginMessageId will contain the unique identifier provided by the plugin in the
            ' previous call to messageRequested.
            '
            ' If messageProcessed is false, Iguana was unable to enqueue the message, and it
            ' should be sent again.

            System.Console.WriteLine("")
            System.Console.WriteLine("*** Message Request Completed (plugin message id: " + inputs.PluginMessageId + ") ***")
         Catch ex As Exception
            System.Console.WriteLine(ex.ToString())
         End Try
      End Sub

      ' This event is triggered when the plugin disconnects from Iguana.
      Public Sub OnDisconnected(ByVal sender As Object, ByVal args As System.EventArgs) Handles source.Disconnected
         ' Note that exceptions can never be thrown outside the handler.
         Try
            System.Console.WriteLine("Source disconnected.")
         Catch ex As Exception
            System.Console.WriteLine(ex.ToString())
         End Try
      End Sub

      Public WithEvents source As New Source
      Private engine As New SourcePluginEngine
      Private lastMessageRequestTime As DateTime = DateTime.Now
      Private random As New Random
      Private logString As New String("")
   End Class

   ' The main entry point for the application.
   Sub Main(ByVal args() As String)
      Try
         If args.Length < 3 Then
            Throw New Exception("Invalid command line arguments.")
         End If

         Dim hostname As String = args(0)
         Dim port As Integer = Integer.Parse(args(1))
         Dim channel As String = args(2)

         Dim sourcePluginExample As New SourcePluginExample
         sourcePluginExample.source.Connect(hostname, port, channel)

         ' Wait for the plugin to disconnect.
         ' Could also use waitForDisconnectWithTimeout() here.
         sourcePluginExample.source.WaitForDisconnect()

         ' Print the reason for disconnection.
         Dim disconnectReason As DisconnectReason = sourcePluginExample.source.DisconnectReason
         System.Console.WriteLine(disconnectReason.Description)
      Catch ex As Exception
         System.Console.WriteLine(ex.ToString())
         System.Console.WriteLine()
         System.Console.WriteLine("This is an Iguana source plugin.  It runs as a command line application")
         System.Console.WriteLine("which connects via TCP/IP to the plugin communication server within Iguana.")
         System.Console.WriteLine("It will be necessary to run a channel in Iguana and set up a channel with")
         System.Console.WriteLine("a From Plugin component for this to connect to.  See:")
         System.Console.WriteLine()
         System.Console.WriteLine("   http://www.interfaceware.com/manual/plugin_setup_vbnet.html")
         System.Console.WriteLine()
         System.Console.WriteLine("Once the channel is set up and running you can connect to it with this usage:")
         System.Console.WriteLine()
         System.Console.WriteLine("  SourcePluginExample <iguana hostname> <plugin communication port> <channel name>")
         System.Console.WriteLine()
         System.Console.WriteLine("The plugin communication port is the port that Iguana listens on for plugin")
         System.Console.WriteLine("communication.")
      End Try
   End Sub
End Module