Dynamic Interface

Looking for Iguana v.5 or v.6? Learn More or see the Help Center.

Dynamic Interface

The static generated interface offers ease of use with Chameleon at the expense of flexibility. The dynamic interface offers an alternative to using stubcode which gives more power, but requires more effort on the part of the programmer. This table summarizes the main differences between the approaches:

	Dynamic Interface	Static Interface
Needs code generation?
Can the compiler find spelling mistakes?
Advantages	Message tables can be explored dynamically and application can be delivered without stubcode.	Guaranteed to avoid the runtime problems caused by typos.
Disadvantages	Cannot avoid the problem caused by typos.	Application has to be delivered with stubcode.
Changing messages and table grammar	Do not need to recompile.	Need to recompile.

To use the dynamic interface to parse a message, these steps must be followed:

Ensure your project references the VMlibrary 1.0 Type Library.
Create an instance of a VMengine object.
Load the message definition file.
Instantiate an empty VMtable object.
Invoke the Parse method on the Engine object to parse the message.
The resulting VMtable object can then be explored using methods which allow access to the columns, rows and sub-tables.

Private Sub btnTest_Click()
   Dim Engine As New VMengine
   Dim MessageTable As New VMtable
   Dim MessageIndex As Long
   Dim Message As String
   
   Message = "MSH|^~\&|REGADT|MCM|RSP1P8|MCM|199601051530|SEC|ADT^A44|00000007|P|2.5" & vbCr
   Message = Message + "EVN|A44|199601051530" & vbCr
   Message = Message + "PID|||MR2^^^XYZ||JONES^WILLIAM^A^JR||19501010|M|||123 EAST STREET^^NY^NY^10021||(212)111-3333|||S||ACCT1" & vbCr
   Message = Message + "MRG|MR1^^^XYZ||ACCT1" & vbCr
   Message = Message + "MRG|MR1^^^XYZ||ACCT1" & vbCr
   Message = Message + "MRG|MR1^^^XYZ||ACCT1" & vbCr
   
   Engine.Load App.Path + "\project.vmd"
   
   Engine.Parse Message, MessageIndex, MessageTable
  
   ' ShowTable is a recursive procedure used to explore the MessageTable.
   ShowTable MessageTable, ""
End Sub

Private Sub ShowTable(Table As VMtable, Indent As String)
   Dim ColumnIndex, SubTableIndex, RowIndex As Long
   Dim Line As String
   
   DisplayOutput "Table: " & Table.TableName
   If Table.CountOfSubTable > 0 Then
      For RowIndex = 0 To Table.CountOfRow - 1
         For SubTableIndex = 0 To Table.CountOfSubTable - 1
            ShowTable Table.SubTable(RowIndex, SubTableIndex), Indent + "   "
         Next
      Next
   Else
      For RowIndex = 0 To Table.CountOfRow - 1
         For ColumnIndex = 0 To Table.CountOfColumn - 1
            Line = Table.ColumnName(ColumnIndex) & "="
            If Table.ColumnType(ColumnIndex) = VMstringType Then
                Line = Line & Table.StringValue(ColumnIndex, RowIndex)
            ElseIf Table.ColumnType(ColumnIndex) = VMdateTimeType Then
                Line = Line & Format(Table.DateTimeValue(ColumnIndex, RowIndex))
            ElseIf Table.ColumnType(ColumnIndex) = VMintegerType Then
                Line = Line & CStr(Table.IntegerValue(ColumnIndex, RowIndex))
            ElseIf Table.ColumnType(ColumnIndex) = VMdoubleType Then
                Line = Line & CStr(Table.DoubleValue(ColumnIndex, RowIndex))
            End If
            DisplayOutput Indent & Line
         Next
      Next
   End If
End Sub

The New Project Window contains an HL7 Project Wizard that illustrates this functionality called Dynamic API Example.


	Note that the message itself is a table. It is necessary to iterate through its sub-tables to get the top level tables in its table grammar.

Products Manual

iNTERFACEWARE

Dynamic Interface